Contract Address Details

/**
* Submitted for verification at blockscout.com on 2021-05-18 11:47:52.940748Z
*/
// File: @openzeppelin\contracts\GSN\Context.sol

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity >=0.4.22 <0.8.0;

/*
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with GSN meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address payable) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes memory) {
        this; // silence state mutability warning without generating bytecode - see https://github.com/ethereum/solidity/issues/2691
        return msg.data;
    }
}

// File: contracts\UserConsentLogsManager.sol



// Import Libraries


/**
 * @title - User Consent Logs Manager
 * @author - Quadrant
 * @notice - A contract to emit user consent events within Quadrant chain that can be trusted by users and regulators
 */

contract UserConsentLogsManager is Context {
    /**
     * @dev Constructor function
     * @notice Set contract deployer as the owner
     */
    constructor() public {
        isOwner[_msgSender()] = true;
    }

    /**
     * @dev Mapping variable to store boolean checks for request type
     * @notice If boolen is true then the request type is performed only by Quadrant for Quadrant Compliance App
     * @notice If boolean is false then anyone can perform this request
     */

    mapping(string => bool) public isAdminRequest;

    mapping(address => bool) internal isOwner;

    /**
     * @dev Throws if the function is not called by the owner
     */
    modifier onlyOwner() {
        require(isOwner[_msgSender()], "No permission");
        _;
    }

    /**
     * @dev Throws if the function is neither called by the owner nor by the requester
     * @param requester - The address of the requester
     */
    modifier eitherOwnerOrRequester(address requester) {
        require(
            isOwner[_msgSender()] || _msgSender() == requester,
            "No permission"
        );
        _;
    }

    /**
     * @notice - Add SDK user audit trail
     * @dev - Used to emit events when a user from publisher's app opts in, opts out, DNS, request or delete data
     */

    event SdkUserConsentAuditTrail(
        string requestId,
        string requestType,
        string regulation,
        address indexed requestedBy,
        address indexed app,
        string deviceId,
        bytes32 indexed data,
        uint256 capturedAt,
        uint8 requestStatus,
        uint8 action
    );

    /**
     * @notice - Add Quadrant Compliance user audit trail
     * @dev - Used to emit events when a user from Quadrant compliance's app (or email) opts in, opts out, DNS, request or delete data
     */

    event QuadrantComplianceUserAuditTrail(
        string requestId,
        string requestType,
        address indexed requestedBy,
        string deviceId,
        bytes32 indexed data,
        uint256 capturedAt,
        uint8 requestStatus,
        uint8 action,
        string requestCameFrom
    );

    /**
     * @dev - Function to set ownership
     * @param inputAddress - The address whose ownership will be added or revoked
     * @param ownerFlag - Boolean value to set. True indicates the address will be set as owner
     * @notice - Access: Only Owner (Quadrant)
     */

    function setOwner(address inputAddress, bool ownerFlag) external onlyOwner {
        isOwner[inputAddress] = ownerFlag;
    }

    /**
     * @dev - Function to set requests that are performed only by admin (Quadrant) for Quadrant compliance app
     * @param requestType - Type of the request
     * @param isOnlyQuadrantRequest - Boolean value to set. True indicates operation performed only by Quadrant
     * @notice - Access: Only Owner (Quadrant)
     */

    function setAdminRequest(
        string memory requestType,
        bool isOnlyQuadrantRequest
    ) external onlyOwner {
        isAdminRequest[requestType] = isOnlyQuadrantRequest;
    }

    /**
     * @dev - Function to emit SDK user event
     * @notice - Emits event when there is a user operation from Publisher's SDK app side
     * @param requestId - The request id in UUID format
     * @param requestType - Type of the request
     * @param regulation - GDPR, CCPA etc.
     * @param requestedBy - Address of the requester (publisher address) or admin (quadrant)
     * @param app - App address
     * @param deviceId - Encrypted device id
     * @param data - SHA256 hash of the json data object. The data will have details of the compliance event
     * @param capturedAt - The 13 digit epoch time when the request was made
     * @param requestStatus - The status of the request (e.g. PENDING, COMPLETED etc - represented in integers)
     * @param action - Indicates if the request is forwarded or not (Default: '')
     * @notice - Access: Either Owner (Quadrant) or the requester
     */

    function addSdkUserConsentAuditTrail(
        string memory requestId,
        string memory requestType,
        string memory regulation,
        address requestedBy,
        address app,
        string memory deviceId,
        bytes32 data,
        uint256 capturedAt,
        uint8 requestStatus,
        uint8 action
    ) external eitherOwnerOrRequester(requestedBy) {
        /// Accept all except Quadrant Compliance App requests
        require(!isAdminRequest[requestType], "Invalid request");

        /// Accept only NULL OR PENDING requestStatus when a non owner calls this function
        if (!isOwner[_msgSender()]) {
            require(
                requestStatus == 0 || requestStatus == 1,
                "Invalid request status"
            );
        }

        /// Emit Event
        emit SdkUserConsentAuditTrail(
            requestId,
            requestType,
            regulation,
            requestedBy,
            app,
            deviceId,
            data,
            capturedAt,
            requestStatus,
            action
        );
    }

    /**
     * @dev - Function to emit compliance app user event
     * @notice - Emits event when there is an operation on Compliance App
     * @param requestId - The request id in UUID format
     * @param requestType - Type of the request
     * @param requestedBy - Address of the requester (Quadrant/admin address)
     * @param deviceId - Encrypted device id
     * @param data - SHA256 hash of the json data object. The data will have details of the compliance event
     * @param capturedAt - The 13 digit epoch time when the request was made
     * @param requestStatus - The status of the request (e.g. PENDING, COMPLETED etc - represented in integers)
     * @param action - Indicates if the request is forwarded or not (Default: '')
     * @param requestCameFrom - Indicates whether the request came via email or compliance app
     * @notice - Access: Only Owner (Quadrant)
     */

    function addQuadrantComplianceUserAuditTrail(
        string memory requestId,
        string memory requestType,
        address requestedBy,
        string memory deviceId,
        bytes32 data,
        uint256 capturedAt,
        uint8 requestStatus,
        uint8 action,
        string memory requestCameFrom
    ) external onlyOwner {
        /// Accept only request types that are performed by Quadrant
        require(isAdminRequest[requestType], "Invalid request");

        /// Emit Event
        emit QuadrantComplianceUserAuditTrail(
            requestId,
            requestType,
            requestedBy,
            deviceId,
            data,
            capturedAt,
            requestStatus,
            action,
            requestCameFrom
        );
    }
}

[{"type":"constructor","stateMutability":"nonpayable","inputs":[]},{"type":"event","name":"QuadrantComplianceUserAuditTrail","inputs":[{"type":"string","name":"requestId","internalType":"string","indexed":false},{"type":"string","name":"requestType","internalType":"string","indexed":false},{"type":"address","name":"requestedBy","internalType":"address","indexed":true},{"type":"string","name":"deviceId","internalType":"string","indexed":false},{"type":"bytes32","name":"data","internalType":"bytes32","indexed":true},{"type":"uint256","name":"capturedAt","internalType":"uint256","indexed":false},{"type":"uint8","name":"requestStatus","internalType":"uint8","indexed":false},{"type":"uint8","name":"action","internalType":"uint8","indexed":false},{"type":"string","name":"requestCameFrom","internalType":"string","indexed":false}],"anonymous":false},{"type":"event","name":"SdkUserConsentAuditTrail","inputs":[{"type":"string","name":"requestId","internalType":"string","indexed":false},{"type":"string","name":"requestType","internalType":"string","indexed":false},{"type":"string","name":"regulation","internalType":"string","indexed":false},{"type":"address","name":"requestedBy","internalType":"address","indexed":true},{"type":"address","name":"app","internalType":"address","indexed":true},{"type":"string","name":"deviceId","internalType":"string","indexed":false},{"type":"bytes32","name":"data","internalType":"bytes32","indexed":true},{"type":"uint256","name":"capturedAt","internalType":"uint256","indexed":false},{"type":"uint8","name":"requestStatus","internalType":"uint8","indexed":false},{"type":"uint8","name":"action","internalType":"uint8","indexed":false}],"anonymous":false},{"type":"function","stateMutability":"nonpayable","outputs":[],"name":"addQuadrantComplianceUserAuditTrail","inputs":[{"type":"string","name":"requestId","internalType":"string"},{"type":"string","name":"requestType","internalType":"string"},{"type":"address","name":"requestedBy","internalType":"address"},{"type":"string","name":"deviceId","internalType":"string"},{"type":"bytes32","name":"data","internalType":"bytes32"},{"type":"uint256","name":"capturedAt","internalType":"uint256"},{"type":"uint8","name":"requestStatus","internalType":"uint8"},{"type":"uint8","name":"action","internalType":"uint8"},{"type":"string","name":"requestCameFrom","internalType":"string"}]},{"type":"function","stateMutability":"nonpayable","outputs":[],"name":"addSdkUserConsentAuditTrail","inputs":[{"type":"string","name":"requestId","internalType":"string"},{"type":"string","name":"requestType","internalType":"string"},{"type":"string","name":"regulation","internalType":"string"},{"type":"address","name":"requestedBy","internalType":"address"},{"type":"address","name":"app","internalType":"address"},{"type":"string","name":"deviceId","internalType":"string"},{"type":"bytes32","name":"data","internalType":"bytes32"},{"type":"uint256","name":"capturedAt","internalType":"uint256"},{"type":"uint8","name":"requestStatus","internalType":"uint8"},{"type":"uint8","name":"action","internalType":"uint8"}]},{"type":"function","stateMutability":"view","outputs":[{"type":"bool","name":"","internalType":"bool"}],"name":"isAdminRequest","inputs":[{"type":"string","name":"","internalType":"string"}]},{"type":"function","stateMutability":"nonpayable","outputs":[],"name":"setAdminRequest","inputs":[{"type":"string","name":"requestType","internalType":"string"},{"type":"bool","name":"isOnlyQuadrantRequest","internalType":"bool"}]},{"type":"function","stateMutability":"nonpayable","outputs":[],"name":"setOwner","inputs":[{"type":"address","name":"inputAddress","internalType":"address"},{"type":"bool","name":"ownerFlag","internalType":"bool"}]}]